proc sort data=BP_analysis_Data;

by sdmvstra sdmvpsu;

run;

Use the SAS procedure, proc sort, to sort the data by the design parameters, strata (sdmvstra) and primary sampling units (sdmvpsu), before running the procedure in SUDAAN.

proc descript data=BP_analysis_Data design=WR noprint

DEFT2 ATLEVEL1=1 ATLEVEL2=2 ;

Use proc descript to specify the dataset (BP_analysis_Data), specify the sample design using the design option WR (with replacement).

Use the noprint option to suppress printing of results. In this example, you will be sending the results to a SAS data file for further calculations and printing in SAS.

Use a DEFT2 statement to request the calculation of the design effect using method 2 (see SUDAAN manual for details on the differing methods for calculating design effect).  Method 2 is the method recommended by NCHS for NHANES data.

The ATLEVEL1=1 and ATLEVEL2=2 options specify the sampling stages (in NHANES, the number of strata is level 1, and the number of PSUs is level 2) for which you want counts per table cell. ATLEV1 is the number of strata with at least one valid observation and ATLEV2 is the number of PSUs with at least one valid observation. These numbers are used to calculate degrees of freedom.

nest sdmvstra sdmvpsu;

Use the nest statement to specify the strata and PSU variables to account for the sample design effects.

Weight wtmec4yr;

Use the weight statement to account for the unequal probability of sampling and nonresponse. In this example, the MEC weight for four years of data is used.

 SUBPOPN riagendr=2 and ridageyr > 19 and ridageyr < 60 ;

Use a subpopn statement to subset on the subgroup of interest. In this example, it is females (riagendr=2) between ages 20-59 years (ridageyr > 19 and ridageyr < 60).

Var hbp;

Use a var statement to set the variable of interest as the percent with high blood pressure. (In order to generate results that are expressed in percent with the condition, this variable was coded as 0=no high blood pressure and 100=those with high blood pressure.)

class race educ;

Use a class statement to set the categorical variables of interest. In this example, race/ethnic group (race) and education level (educ).

Tables race*educ ;

Use a tables statement to request prevalence of high blood pressure stratified on education level (educ) within each race/ethnic group (race).

Output   atlev1=numstrat atlev2=numpsu  mean=mean semean=semean

NSUM=N deffmean /  filetype=SAS filename=test1 replace;

Use the output statement to request output of results to a SAS data file (filetype=SAS) called test1 (filename=test1). 

Use a replace statement to replace this file each time this program is run and updated with the latest results.

Use an atlev1 option to create the SAS data variable, numstrat, with the value obtained from counting the number of strata in each subdomain requested with at least one valid observation.

Use an atlev2 option to create a SAS variable, numpsu, with the value obtained from counting the number of PSU's in each subdomain requested with at least one valid observation.

Use the mean option to output the mean to the SAS data set.  In this example, the mean is the percent of individuals at each level with high blood pressure.

Use the semean option to output the standard error of the mean estimated above to the SAS dataset.

Use the nsum option to create the variable N in the SAS dataset which gives the number of observations in each level in each subdomain requested in the table statement.

Use the deffmean option to output the design effect for each subdomain requested.

Rformat race racef.;

Rformat educ educf.;

Use an  rformat  option to specify formats for the levels of each categorical variable in the tables statement as needed. Format statements for each variable must be listed individually.  In this example, you are setting the formats for the race/ethnic group (race) and education level (educ) variables.

Rtitle "Prevalence of high blood pressure by race and education level for women age 20-59";

Use the rtitle option to set the title for output for procedure.

Proc sort data=test1;

   by race educ;

run;

DATA test2;  SET test1;

percent=round(mean,.01);

sepercent=round(semean,.01);

df=atlev2-atlev1;

tlow=tinv(.025,df);

tup=tinv(.975,df);

rse=round((semean/mean)*100,.01);

rsese=round((1/sqrt(df)),.01);

ll=round((mean+tlow*semean),.01);

ul=round((mean+tup*semean),.01);

proc print;

VAR Race Educ Percent Sepercent df deffmean tup ll ul;

title1 'Degrees of Freedom and Wald 95% Confidence Interval';

title2 'Race and Education of High Blood Pressure NHANES1999-2002';

run;

Use the var statement to indicate variables of interest (race (race); education level (educ); percent of people in the category (percent); standard error of the percent (sepercent );  degrees of freedom (df); design effect (deffmean); t-statistic upper limit (tup); lower confidence limit (ll); and upper confidence limit (ul).