pro plot_antenna, colors=colors

if n_elements( colors ) lt 3 then begin
      ; as per Dave Gates "Patented Color Table":
   red =   [0,159,186,214,241,255,255,255,255,  0,135,255,255,217,220,190]
   green = [0,  0, 17, 52, 88,124,160,196,232, 72,255,174,255,217, 12,190]
   blue =  [0,  0,  0,  0,  0,  0, 58,133,207,255,  0,  0,255,217,103,190]
   colors = lonarr( 3 )
   desired = [11,13,14]  
   for i=0,n_elements( colors )-1 do colors[i] =  $
     nearest_color_index( red[ desired[i]], green[ desired[i]],blue[ desired[i]] )
endif

box_z = [-.00635,.00635,0.00635,-.00635,-.00635]
box_r = [0.,0.,.0508,.0508,0.]
r_curv = 23.15*.0254
r_cent = 40.15*.0254
t_boron = -.03
d_strap = 0.625*.0254
t_strap = 0.375*.0254
theta_max = !pi*11.25/180
r_wall = 1.7
;
; Boron
;
theta = theta_max*(findgen(21)/10-1.)
offset_parallel = (0.5+findgen(13))*.0254
offset_r = -1.0*sin(theta_max)*offset_parallel
offset_z = cos(theta_max)*offset_parallel
r_start = (r_curv + t_boron)*cos(theta_max)+r_cent
z_start = (r_curv + t_boron)*sin(theta_max)
r_boron = [r_wall,r_start+reverse(offset_r), $
  (r_curv+t_boron)*cos(theta)+r_cent,r_start+offset_r,r_wall]
z_boron = [-1.*z_start-max(offset_z),-1.*z_start-reverse(offset_z), $
  (r_curv+d_strap)*sin(theta),z_start+offset_z,z_start+max(offset_z)]
polyfill,r_boron,z_boron,color=colors[1]
oplot,r_boron,z_boron
;
;Antenna strap
;
theta = theta_max*(findgen(21)/10-1.)
offset_parallel = (0.5+findgen(12))*.0254
offset_r = -1.0*sin(theta_max)*offset_parallel
offset_z = cos(theta_max)*offset_parallel
r_start = (r_curv + d_strap)*cos(theta_max)+r_cent
z_start = (r_curv + d_strap)*sin(theta_max)
r_antenna = [r_start+reverse(offset_r), $
  (r_curv+d_strap)*cos(theta)+r_cent,r_start+offset_r, $
   r_start+reverse(offset_r)+t_strap, $
   (r_curv+d_strap+t_strap)*cos(theta)+r_cent, $
   r_start+offset_r+t_strap]
z_antenna = [-1.*z_start-reverse(offset_z), $
   (r_curv+d_strap)*sin(theta),z_start+offset_z, $
    z_start+reverse(offset_z), $
    (r_curv+d_strap+t_strap)*reverse(sin(theta)), $
    -1.*z_start-offset_z]
polyfill,r_antenna,z_antenna,color=colors[0]
oplot,r_antenna,z_antenna
;
; Horizontal part of straps
;
polyfill,r_start+min(offset_r)+[0.,0.,.14,.14,0.], $
   z_start+max(offset_z)+[0.,.01,.01,0.,0.],color=colors[0]
oplot,r_start+min(offset_r)+[0.,0.,.14,.14,0.], $
   z_start+max(offset_z)+[0.,.01,.01,0.,0.]
polyfill,r_start+min(offset_r)+[0.,0.,.13,.13,0.], $
   -1.0*(z_start+max(offset_z)+[0.,.01,.01,0.,0.]),color=colors[0]
oplot,r_start+min(offset_r)+[0.,0.,.13,.13,0.], $
   -1.0*(z_start+max(offset_z)+[0.,.01,.01,0.,0.])
;
;Faraday shields on curved part of antenna
;
theta = !pi*2.5*(findgen(9) - 4.0)/180
box2_r = cos(theta)#(r_curv+box_r)-sin(theta)#box_z
box2_z = sin(theta)#(r_curv+box_r)+cos(theta)#box_z
for i=0,8 do polyfill,box2_r(i,*)+r_cent,box2_z(i,*),$
 color=colors[2]
 ;
;Faraday shields on straight parts of antenna
;
box3_r = cos(theta_max)*(r_curv+box_r)-sin(theta_max)*box_z
box3_z = sin(theta_max)*(r_curv+box_r)+cos(theta_max)*box_z
offset_parallel = (0.5+findgen(11))*.0254
offset_r = -1.0*sin(theta_max)*offset_parallel
offset_z = cos(theta_max)*offset_parallel
for i = 0,10 do polyfill,box3_r+r_cent+offset_r[i],box3_z+offset_z[i], $
  color=colors[2]
for i = 0,10 do polyfill,box3_r+r_cent+offset_r[i], $
 -1.0*(box3_z+offset_z[i]),color=colors[2]
end