/*  This is the FlAniS -- Flash version of the AnimationS applet.
This code is Copyright(C) 2008 by Tom Whittaker. You may use
this for any lawful purpose, and we are not responsible for what you
do with it. It was developed as an outcome of the  VISIT Project and
uses many classes from the VISITview collaborative training / distance
learning tool. 

*/

// this is compiled with the mxmlc using the flanis.mxml template...

package {
  import mx.controls.Button;
  import mx.controls.CheckBox;
  import mx.controls.Label;
  import mx.controls.HSlider;
  import mx.controls.RadioButton;
  import mx.controls.RadioButtonGroup;
  import mx.controls.ProgressBar;
  import mx.controls.Alert;
  import mx.core.*;
  import mx.containers.HBox;
  import mx.containers.VBox;
  import mx.containers.Canvas;
  import mx.core.UIComponent;
  import mx.events.SliderEvent;
  import mx.utils.StringUtil;
  import flash.display.Loader;
  import flash.display.Bitmap;
  import flash.display.Sprite;
  import flash.display.BitmapData;
  import flash.display.Graphics;
  import flash.events.Event;
  import flash.events.MouseEvent;
  import flash.events.IOErrorEvent;
  import flash.net.URLRequest;
  import flash.geom.Point;
  import flash.geom.Rectangle;
  import flash.geom.Matrix;
  import flash.geom.ColorTransform;

  import flash.utils.Timer;
  import flash.events.TimerEvent;
  import flash.system.System;

  import flash.net.*;
  import flash.text.*;
  


  public class FlAniS {

    private var background:int;
    private var foreground:int;
    private var usingIP:Boolean;
    private var onlyShowFirstImage:Boolean;
    private var quietReload:Boolean;
    private var quietLoadem:Boolean;
    private var noControls:Boolean;
    private var useProgressBar:Boolean;
    private var isLoading:Boolean;
    private var countFrames:int;
    private var doExcludeCaching:Boolean;
    private var excludeCaching:String;
    private var useCaching:Boolean;
    private var useAntiCaching:Boolean;
    private var antiCacheIndex:int;
    private var baseStatic:Boolean;
    private var imageBase:String;
    private var s:Array;
    private var its:int;

    private var zoom:Button;
    private var zoomLabelTrue:String;
    private var zoomLabelFalse:String;
    private var keepZoom:Boolean;
    private var activeZoom:Boolean;
    private var zoomXFactor:Number;
    private var zoomYFactor:Number;
    private var zoomXBase:Number;
    private var zoomYBase:Number;
    private var isZooming:Boolean;
    private var enableZooming:Boolean;
    private var frameLabelWidth:int;
    private var frameLabelField:Label;
    private var hasFrameLabel:Boolean;
    private var frameLabels:Array;

    private var doLayoutControls:Boolean;
    private var useBottomControls:Boolean;
    private var looprock:Button;
    private var looprockLabelTrue:String;
    private var looprockLabelFalse:String;
    private var isLoopRock:Boolean;
    private var loopDirection:int;
    private var isRocking:Boolean;
    private var autoOnOff:Button;
    private var autoOnOffLabelTrue:String;
    private var autoOnOffLabelFalse:String;
    private var refreshRate:int;
    private var refreshTimer:Timer;
    private var autoState:Boolean;
    private var refresh:Button;
    private var isAutoRefresh:Boolean;
    private var showAllOnOff:Boolean;
    private var onOffWidth:int;
    private var onOffHeight:int;
    private var onOffSpacing:int;
    private var onOffState:Array;
    private var onOffBM:Bitmap;
    private var onOffRect:Rectangle;
    private var onOffBMD:BitmapData;
    private var onOffUI:UIComponent;
    private var onOffSprite:Sprite;
    private var isOnOff:Boolean;
    private var incFrame:int;

    private var stepBack:Button;
    private var stepForward:Button;
    private var isStepping:Boolean;
    private var stepFirst:Button;
    private var stepLast:Button;

    private var setFrameScrollbar:HSlider;
    private var setFrameText:String;
    private var isSetFrameScrollbar:Boolean;

    private var setFaderScrollbar:HSlider;
    private var setFaderText:String;
    private var isFader:Boolean;
    private var faderFrame:int;
    private var faderImages:Array;
    private var isShowingFrames:Boolean;

    private var faderLabel:String;
    private var startFrame:int;
    private var basename:String;
    private var baseNumber:int;
    private var numFrames:int;
    private var currentFrame:int;
    private var deadFrames:int;
    private var firstFrame:int;
    private var lastFrame:int;


    private var vb:VBox;
    private var vbc:VBox;
    private var hb:HBox;
    private var controlBox:HBox;
    private var overlayControlBox:HBox;
    private var overlayControlContainer:VBox;
    private var speed:HSlider;
    private var dwell:int;
    private var addDwell:int;
    private var pauseOnLast:int;
    private var pausePercent:int;
    private var startstop:Button;
    private var startstopLabelTrue:String;
    private var startstopLabelFalse:String;
    private var bm:Bitmap;
    private var grandma:Application;
    private var mom:Canvas;
    private var sp:Sprite;
    private var timer:Timer;
    private var isLooping:Boolean;
    private var wasLooping:Boolean;
    private var isOverlay:Boolean;
    private var overlay:Array;
    private var overlayLinks:Array;
    private var overlayOrder:Array;
    private var overlayHidden:Array;
    private var overlayStatic:Array;
    private var overlayZoom:Array;
    private var overlayTransparentAmount:Array;
    private var ct:ColorTransform;
    private var transparency:int;
    private var numOverlayLabels:int;

    private var fnList:Array;
    private var biList:Array;
    private var olList:Array;
    private var fnDwell:Array;
    private var minDwell:int;


    private var pbar:ProgressBar;
    private var totalFrames:int;
    private var initialLoad:Boolean;
    private var imgList:Array;
    private var singleImage:Array;
    private var imgSmoothList:Array;
    private var imgUIBack:UIComponent;
    private var imgLoaderList:Array;
    private var imgLoaderInfoList:Array;
    private var imgZoomableList:Array;
    private var preserve:Array;
    private var preRect:Rectangle;
    private var prePoint:Point;
    private var xImage:int;
    private var yImage:int;
    private var xScreen:int;
    private var yScreen:int;
    private var xMove:int;
    private var yMove:int;
    private var bmBack:Bitmap;
    private var bmBackground:BitmapData;
    private var bmBackCreated:Boolean
    private var bmBackLoaded:Array
    private var bmWidth:int;
    private var bmHeight:int;
    private var userWindowSize:Boolean;
    private var imgWidth:int;
    private var imgHeight:int;

    private var backSprite:Sprite;

    private var upperLeft:Point;
    private var imgRect:Rectangle;
    private var bmRect:Rectangle;
    private var isDragging:Boolean;

    private var paramNames:Array;
    private var paramValues:Array;
    private var pLabels:Array


    // Application point of entry

    public static function main():void {
      var ec:FlAniS = new FlAniS();
      ec.layout();
    }

    public function layout():void {

      grandma = Application(Application.application);
      grandma.layout="absolute";
      grandma.frameRate = 1;
      mom = new Canvas();
      mom.height = grandma.height;
      mom.width = grandma.width;
      mom.setStyle("backgroundColor", grandma.getStyle("backgroundColor"));
      grandma.addChild(mom);


      vb = new VBox();
      vb.move(0,3);
      vb.width=mom.width;
      vb.setStyle("horizontalAlign","center");
      vb.setStyle("verticalGap",2);
      mom.addChild(vb);

      initialLoad = true;
      currentFrame = 0;
      bmBackCreated = false;
      zoomXFactor = 1.0;
      zoomYFactor = 1.0;
      isZooming = false;
      enableZooming = false;
      isDragging = false;
      isOverlay = false;
      incFrame = 1;
      isFader = false;
      preRect = new Rectangle();
      prePoint = new Point();

      upperLeft = new Point(0,0);

      ct = new ColorTransform(1.0,1.0,1.0,1.0);

      // all set up must be serialized, since there is no
      // other way to do it...hmmmm....

      var configLoader:URLLoader = new URLLoader();
      configLoader.dataFormat = URLLoaderDataFormat.TEXT;
      configLoader.addEventListener(Event.COMPLETE, configLoaded);

      // see if name supplied in Flashvars
      var cfname:String = grandma.parameters.configFilename;
      if (cfname == null) cfname = "flanis.cfg";
      trace ("cfname = "+cfname);

      isLoading = false;

      var request:URLRequest = new URLRequest(cfname);

      // turn off caching ?
      request.requestHeaders.push(new URLRequestHeader("Cache-Control","no-store,max-age=0,no-cache,must-revalidate"));
      request.requestHeaders.push(new URLRequestHeader("Expires","Mon, 26 Jul 1997 05:00:00 GMT"));
      request.requestHeaders.push(new URLRequestHeader("Pragma","no-cache"));

      configLoader.load(request);
    }

    // handle the config info once the text file is loaded...
    private function configLoaded(event:Event) : void {

      var cfl:URLLoader = URLLoader(event.target);

      var lines:Array = cfl.data.split("\n");
      paramNames = new Array();
      paramValues = new Array();

      // first, parse the basic requests
      for (var i:int=0; i<lines.length; i++) {
        if (lines[i].length < 5) continue;
        if (lines[i].indexOf("=") < 1) continue;

        trace("text:  "+lines[i]);
        var pair:Array = lines[i].split("=");
        paramNames.push(StringUtil.trim(pair[0]).toLowerCase());

        var args:Array = pair[1].split(",");

        // scan the array and trim the values
        for (var k:int=0; k<args.length; k++) {
          args[k] = StringUtil.trim(args[k]);
        }
        trace("name="+paramNames[paramNames.length-1]+"  args = "+args);
        paramValues.push(args);
      }


      // done with setup for getParameter()....

      s = getParameter("height");
      if (s != null) {
        mom.height = parseInt(s[0]);
      }

      s = getParameter("width");
      if (s != null) {
        mom.width = parseInt(s[0]);
        vb.width = mom.width;
      }

      background = mom.getStyle("backgroundColor");
      s = getParameter("backcolor");
      if (s != null) {
        background = parseHex(s[0]);
        mom.setStyle("backgroundColor", background);
      }

      foreground = mom.getStyle("color");
      s = getParameter("forecolor");
      if (s != null) {
        foreground = parseHex(s[0]);
        mom.setStyle("color", foreground);
      }

      trace("font size = "+mom.getStyle("fontSize"));
      s = getParameter("font_size");
      if (s != null) {
        mom.setStyle("fontSize",parseInt(s[0]));
      }

      usingIP = false;
      s = getParameter("use_IP");
      if (s != null && s[0].toLowerCase() == "true") usingIP = true;

      onlyShowFirstImage = false;
      s = getParameter("only_show_first_image");
      if (s != null && s[0].toLowerCase() == "true") onlyShowFirstImage = true;

      quietReload = false;
      quietLoadem = false;
      s = getParameter("quiet_reload");
      if (s != null && s[0].toLowerCase() == "true") quietReload = true;
      if (s != null && s[0].toLowerCase() == "very") {
        quietReload = true;
        quietLoadem = true;
      }

      noControls = false;
      s = getParameter("no_controls");
      if (s != null && s[0].toLowerCase() == "true") noControls = true;

      useProgressBar = true;
      s = getParameter("use_progress_bar");
      if (s != null && s[0].toLowerCase() == "false") useProgressBar = false;

      doExcludeCaching = false;
      s = getParameter("exclude_caching");
      if (s != null) {
        doExcludeCaching = true;
        excludeCaching = s[0];
      }

      useCaching = false;
      s = getParameter("use_caching");
      if (s != null && s[0].toLowerCase() == "true") useCaching = true;

      useAntiCaching = true;
      s = getParameter("use_anti_caching");
      if (s != null) {
        if (s[0].toLowerCase() == "true") useAntiCaching = true;
        if (s[0].toLowerCase() == "false") useAntiCaching = false;
      }

      baseStatic = false;
      s = getParameter("base_static");
      if (s != null && s[0].toLowerCase() == "true") baseStatic = true;

      s = getParameter("image_base");
      if (s != null) imageBase = s[0];

      fnList = new Array();
      s = getParameter("filenames");
      if (s != null) {
        fnList[0] = s;
        trace("got filenames="+fnList[0]);
        numFrames = fnList[0].length;
        lastFrame = numFrames - 1;
        firstFrame = 0;
        currentFrame = 0;
      }

      keepZoom = false;
      s = getParameter("keep_zoom");
      if (s != null && s[0].toLowerCase() == "true") keepZoom = true;

      activeZoom = false;
      s = getParameter("active_zoom");
      if (s != null && s[0].toLowerCase() == "true") activeZoom = true;
      enableZooming = activeZoom;

      refreshRate = 1;
      isAutoRefresh = false;
      s = getParameter("auto_refresh");
      if (s != null) {
        refreshRate = parseInt(s[0]);
        refreshTimer = new Timer(refreshRate*60*1000);
        refreshTimer.addEventListener(TimerEvent.TIMER, refreshImages, false, 0, true);
        isAutoRefresh = true;
      }

      startFrame = 0;
      s = getParameter("start_frame");
      if (s != null) startFrame = parseInt(s[0]);

      fnDwell = new Array();
      s = getParameter("dwell_rates");
      if (s != null) {
        for (i=0; i<s.length; i++) {
          fnDwell.push( parseInt(s[i]));
        }
      }

      frameLabelWidth = 100;
      s = getParameter("frame_label_width");
      if (s != null) frameLabelWidth = parseInt(s[0]);

      minDwell = 30;
      s = getParameter("minimum_dwell");
      if (s != null) minDwell = parseInt(s[0]);
      if (minDwell < 20) minDwell = 20;

      isLooping = true;
      s = getParameter("start_looping");
      if (s != null) {
        if (startsWith(s[0],"f") || startsWith(s[0],"F") ) {
          isLooping = false;
        }
      }
      wasLooping = isLooping;

      s = getParameter("basename");
      if (s == null) s = getParameter("basenames");
      if (s != null) {
        basename = s[0];
        baseNumber = 0;
        s = getParameter("base_starting_number");
        if (s!= null) baseNumber = parseInt(s[0]);
        s = getParameter("num_frames");
        if (s == null) s = getParameter("num_images");
        if (s == null) {
          trace("Problem with config -- no num_frames parameter!");
        }
        numFrames = parseInt(s[0]);
        lastFrame = numFrames - 1;
        fnList[0] = getNamesUsingBaseName(basename, numFrames);
      }


      s = getParameter("overlay_filenames");
      if (s !=null) {
        trace("got overlays = "+s);
        for (var m:int = 1; m<s.length+1; m++) {
          trace("olList m = "+m);
          fnList[m] = s[m-1].split("&");
          trace("  number="+fnList[m].length);
          for (var n:int=0; n<fnList[m].length; n++) {
            trace("   added:"+fnList[m][n]);
            fnList[m][n] = StringUtil.trim(fnList[m][n]);
          }

        }
      }


      // now pick up params with no associated widget....
      s = getParameter("rate");
      dwell = 300;
      if (s != null) {
        dwell = 10000/parseInt(s[0]);
        trace ("dwell ==== "+dwell);
        if (dwell < 5 || dwell > 30000) {
          dwell = 300;
          Alert("Invalid value for 'rate' parameter....");
        }
      }

      s = getParameter("rocking");
      if (s != null) {
        if (startsWith(s[0],"t") || startsWith(s[0],"T")) isRocking=true;
      } else {
        isRocking = false;
      }

      s = getParameter("loop");


      s = getParameter("pause");
      pauseOnLast = 0;
      if (s != null) {
        pauseOnLast = parseInt(s[0]);
        trace ("pause on last = "+pauseOnLast);
        if (pauseOnLast < 0 || pauseOnLast > 20000) {
          pauseOnLast = 0;
          Alert("Bad value for 'pause' parameter = "+pauseOnLast);
        }
      }

      s = getParameter("pause_percent");
      pausePercent = 0;
      if (s != null) {
        pausePercent = parseInt(s[0]);
        if (pausePercent < 0 || pausePercent > 20000) {
          pausePercent = 0;
          Alert("Bad value for 'pause' parameter = "+pausePercent);
        }

      }

      s = getParameter("transparency");
      transparency = 0x00000000;
      if (s != null) {
        transparency = parseHex(s[0]);
        trace("transparency set to = "+transparency);
      }


      s = getParameter("image_preserve");
      if (s != null) {
        if (s.length % 4 != 0) {
          Alert.show("image_preserve -- incorrect number of parameters!");
          preserve = null;
        } else {
          preserve = new Array(s.length);
          for (i = 0; i<s.length; i++) {
            preserve[i] = parseInt(s[i]);
          }
        }
      }

      userWindowSize = false;
      zoomXBase = 1.0;
      zoomYBase = 1.0;
      s = getParameter("image_window_size");
      if (s != null) {
        bmWidth = parseInt(s[0]);
        bmHeight = parseInt(s[1]);
        bmRect = new Rectangle(0,0,bmWidth, bmHeight);
        userWindowSize = true;
      }

      // not implemented...yet....
      s = getParameter("initial_zoom_state");
      s = getParameter("fade");
      s = getParameter("blank_screen");
      s = getParameter("overlay_locations");
      s = getParameter("image_size");

      // control layout must be done after the image info is available...

      doLayoutControls = true;

      // timer for animation
      timer = new Timer(dwell);
      timer.addEventListener(TimerEvent.TIMER, showFrames, false, 0, true);

      getImageFilenames();

    }


    private function getImageFilenames():void {

      isLoading = true;
      countFrames =0;
      var s:Array = getParameter("file_of_filenames");
      if (s != null) {
        fnList = new Array();
        var fnLoader:URLLoader = new URLLoader();
        fnLoader.dataFormat = URLLoaderDataFormat.TEXT;
        fnLoader.addEventListener(Event.COMPLETE, doneGettingFilenames);
        fnLoader.addEventListener(IOErrorEvent.IO_ERROR, errorLoadingFilenames);

        try {

          var fofName:String = s[0];

          if (useAntiCaching && fofName.indexOf("?") == -1) {
            antiCacheIndex = Math.random()*1677216.0;
            fofName = StringUtil.trim(s[0])+"?"+antiCacheIndex;
          }
          var request:URLRequest = new URLRequest(fofName);

          // turn off caching ?
          request.requestHeaders.push(new URLRequestHeader("Cache-Control","no-store,max-age=0,no-cache,must-revalidate"));
          request.requestHeaders.push(new URLRequestHeader("Expires","Mon, 26 Jul 1997 05:00:00 GMT"));
          request.requestHeaders.push(new URLRequestHeader("Pragma","no-cache"));

          fnLoader.load( request);

        } catch (ioe:Error) {
          trace("Unable to load configuration file: "+s[0]+"  Error: "+ioe);
          Alert.show("Unable to load configuration file: "+s[0]+"  Error: "+ioe);
        }
        
      } else {
        doneGettingFilenames(null);
      }
    }


    private function doneGettingFilenames(event:Event) : void {

      if (event != null) {

        frameLabels = getParameter("frame_label");
        if (frameLabels == null) frameLabels = new Array();
        var fnl:URLLoader = URLLoader(event.target);
        var lines:Array = fnl.data.split("\n");
        var firstTime:Boolean = true;

        // first push for background ([0])
        fnList.push(new Array());

        for (var i:int=0; i<lines.length; i++) {
          trace("fof reading line = "+lines[i]);

          lines[i] = StringUtil.trim(lines[i]);
          if (lines[i].slice(0,1) == "#") continue;
          if (lines[i].length < 2) continue;

          var begindex:int = lines[i].indexOf("\"");
          trace("Looking for quote mark, index="+begindex);
          if (begindex >= 0) {
            var endindex:int = lines[i].lastIndexOf("\"");
            if (begindex == endindex) {
              trace("Error processing frameLabel in "+lines[i]);
              hasFrameLabel = false;
              frameLabels.push(" ");
            } else {
              hasFrameLabel = true;
              frameLabels.push(lines[i].substring(begindex+1,endindex));
            }

            lines[i] = 
               (lines[i].substring(0,begindex)+lines[i].substring(endindex+1));
          }

          lines[i] = StringUtil.trim(lines[i]);
          trace("now lines = "+lines[i]);

          begindex = lines[i].indexOf(" [");
          trace("Looking for bracket, index="+begindex);
          if (begindex >= 0) {
            endindex = lines[i].lastIndexOf("]");
            if (begindex == endindex) {
              trace("Error processing frameDwell in "+lines[i]);
              fnDwell.push("300");
            } else {
              fnDwell.push(lines[i].substring(begindex+1,endindex));
            }

            lines[i] = 
               (lines[i].substring(0,begindex)+lines[i].substring(endindex+1));
          }

          trace("now lines = "+lines[i]);

          lines[i] = StringUtil.trim(lines[i]);
          var inx:int = lines[i].indexOf(" ");
          trace("Looking for space, index="+inx);

          if (inx > 0) {
            var leftHand:String = StringUtil.trim(lines[i].substring(0,inx));
            var rightHand:String = StringUtil.trim(lines[i].substring(inx));
            fnList[0].push(leftHand);

            var lt:Array = rightHand.split("=");
            trace("rightHand = "+rightHand);
            trace("lt[0] = "+lt[0]);
            trace("lt[1] = "+lt[1]);

            if (lt.length != 2) {
              trace("Error processing overlay= in "+lines[i]);
            }

            // comma-separated list of overlay names for this frame...
            if (StringUtil.trim(lt[0]) == "overlay") {
              var olnames:Array = lt[1].split(",");

              for (var k:int = 0; k<olnames.length; k++ ) {
                if (firstTime) fnList.push(new Array());
                fnList[k+1].push (StringUtil.trim(olnames[k])); 
              }
              firstTime = false;

            } else {
              trace("Error processing overlay name in "+lines[i]);
            }


          } else {

            // just the background filename given -- push it onto the array.
            fnList[0].push(lines[i]);
          }

          
        }
      }

      loadUpImages();
       
    }


    private function loadUpImages(): void {

      if (initialLoad) {
        imgList = new Array(fnList.length);
        singleImage = new Array(fnList.length);
        imgLoaderList = new Array(fnList.length);
        imgLoaderInfoList = new Array(fnList.length);
        bmBackLoaded = new Array(fnList.length);
        overlayStatic = new Array(fnList.length);
        for (var m:int=0; m<fnList.length; m++) {
           overlayStatic[m] = false;
        }
        overlayStatic[0] = baseStatic;
      }

      totalFrames = 0;
      numFrames = fnList[0].length;
      lastFrame = numFrames -1;

      // create a list for image load completed
      for (var i:int=0; i<fnList.length; i++) {

        if (!initialLoad && overlayStatic[i]) continue;

        var bll:Array = new Array(fnList[i].length);
        singleImage[i] = true;

        for (var k:int = 0; k<fnList[i].length; k++ ) {
          bll[k] = false;
          if (fnList[i][k] != fnList[i][0]) singleImage[i] = false;
          totalFrames = totalFrames + 1;
        }

        if (singleImage[i]) totalFrames = totalFrames - (fnList[i].length - 1);
        bmBackLoaded[i] = bll;
      }

      trace("Total Frames = "+totalFrames);
      trace("Num of layers = "+fnList.length);

      if (useProgressBar) {
        pbar = new ProgressBar();
        pbar.labelPlacement="center";
        pbar.label="Reading image files";
        pbar.indeterminate = false;
        pbar.mode = "manual";
        pbar.setProgress(0,totalFrames);
        pbar.width=200;
        pbar.move(mom.width/2-100, mom.height/2);
        mom.addChild(pbar);
      }


      if (doLayoutControls) {
        layoutControls();
      }

      getImages();

    }


    private function layoutControls():void {

      // now analyze the 'control' parameters -- only the first time...
      trace("in doLayoutControls..............................");
      hasFrameLabel = false;
      isLoopRock = false;
      loopDirection = 1;
      isOnOff = false;
      onOffUI = null;
      autoState = false;
      isStepping = false;
      useBottomControls = false;
      var tips:Array;

      imgSmoothList = new Array(fnList.length);
      imgZoomableList = new Array(fnList.length);
      for (var h:int=0; h<fnList.length; h++) {
        imgZoomableList[h] = true;
        imgSmoothList[h] = false;
      }


      for (var ctb:int=0; ctb<2; ctb++) {

        vbc= new VBox();
        vbc.setStyle("horizontalAlign","center");
        vbc.setStyle("verticalGap",0);

        trace("ctb = "+ctb);

        if (ctb == 0) {
          s = getParameter("controls");
          tips = getParameter("controls_tooltip");
        } else {
          s = getParameter("bottom_controls");
          tips = getParameter("bottom_controls_tooltip");
        }

        trace("s = "+s);

        if (s != null) {
          controlBox = new HBox();
          controlBox.height = 40;
          controlBox.setStyle("verticalGap","0");
          controlBox.setStyle("horizontalGap","5");
          overlayControlBox = null;
          onOffUI = null;
          var gotControls:Boolean = false;

          for (var cn:int=0; cn<s.length; cn++) {

            if (s[cn] == "startstop") {
              startstop = new Button();
              pLabels = getParameter("startstop_labels");
              if (pLabels == null) {
                startstopLabelFalse= "Start";
                startstopLabelTrue = " Stop ";
              } else {
                startstopLabelTrue = pLabels[0];
                startstopLabelFalse = pLabels[1];
                if (pLabels.length == 3) {
                  startstop.width = parseInt(pLabels[2]);
                }

              }

              if (isLooping) {
                startstop.label=startstopLabelTrue;
              } else {
                startstop.label=startstopLabelFalse;
              }

              startstop.addEventListener(MouseEvent.CLICK, bclick);
              if (tips != null) startstop.toolTip = tips[cn];
              controlBox.addChild(startstop);
              gotControls = true;

            } else if (s[cn] == "speed") {
              speed = new HSlider();
              speed.setStyle("labelOffset",0);
              pLabels = getParameter("speed_label");
              if (pLabels == null) {
                speed.labels = [" ","Set Animation Speed"," "];
              } else {
                speed.labels = [" ",pLabels[0]," "];
                if (pLabels.length == 2) {
                  speed.width = parseInt(pLabels[1]);
                }
              }
              speed.showDataTip = false;
              speed.maximum = 1000;
              speed.minimum = 0;
              speed.value = 700;
              speed.liveDragging = true;
              speed.addEventListener(SliderEvent.CHANGE, changeSpeed);
              if (tips != null) speed.toolTip = tips[cn];
              controlBox.addChild(speed);
              gotControls = true;

            } else if (s[cn] == "framelabel") {
              frameLabelField = new Label();
              frameLabelField.width = frameLabelWidth;
              frameLabelField.height = 20;
              frameLabelField.opaqueBackground = background;
              frameLabelField.setStyle("color",foreground);
              frameLabelField.graphics.lineStyle(1,foreground);
              frameLabelField.graphics.drawRect(0,0,frameLabelWidth,20);
              frameLabelField.text = " ";

              hasFrameLabel = true;
              if (tips != null) frameLabelField.toolTip = tips[cn];
              controlBox.addChild(frameLabelField);
              gotControls = true;

            } else if (s[cn] == "looprock") {
              looprock = new Button();
              pLabels = getParameter("looprock_labels");
              if (pLabels == null) {
                looprockLabelTrue = "Loop";
                looprockLabelFalse = "Rock";
              } else {
                looprockLabelTrue = pLabels[0]; 
                looprockLabelFalse =  pLabels[1];
                if (pLabels.length == 3) {
                  looprock.width = parseInt(pLabels[2]);
                }
              }

              if (isRocking) {
                looprock.label = looprockLabelTrue;
              } else {
                looprock.label = looprockLabelFalse;
              }

              looprock.addEventListener(MouseEvent.CLICK, bclick);
              isLoopRock = true;
              if (tips != null) looprock.toolTip = tips[cn];
              controlBox.addChild(looprock);
              gotControls = true;

            } else if ( (s[cn].indexOf("autotoggle") == 0) ||
                        (s[cn].indexOf("autorefresh") == 0) ) {
              autoOnOff = new Button();
              pLabels = getParameter("autotoggle_labels");
              if (pLabels == null) pLabels = getParameter("autorefresh_labels");
              if (pLabels == null) {
                autoOnOffLabelTrue = "Auto On ";
                autoOnOffLabelFalse = "Auto Off";
              } else {
                autoOnOffLabelTrue = pLabels[0]; 
                autoOnOffLabelFalse =  pLabels[1];
                if (pLabels.length == 3) {
                  autoOnOff.width = parseInt(pLabels[2]);
                }
              }

              if (!isAutoRefresh) {
                
                refreshRate = 1;
                refreshTimer = new Timer(refreshRate*60*1000);
                refreshTimer.addEventListener(TimerEvent.TIMER, refreshImages, false, 0, true);
                isAutoRefresh = true;
              }

              if (s[cn].indexOf("/off") > 0) {
                autoOnOff.label = autoOnOffLabelTrue;
                autoState = false;
                refreshTimer.stop();
              } else {
                autoOnOff.label = autoOnOffLabelFalse;
                autoState = true;
              }
              if (tips != null) autoOnOff.toolTip = tips[cn];
              autoOnOff.addEventListener(MouseEvent.CLICK, bclick);
              controlBox.addChild(autoOnOff);
              gotControls = true;

            } else if (s[cn] == "refresh") {
              refresh = new Button();
              pLabels = getParameter("refresh_label");
              if (pLabels == null) {
                refresh.label = "Refresh";
              } else {
                refresh.label = pLabels[0];
                if (pLabels.length == 2) {
                  refresh.width = parseInt(pLabels[1]);
                }
              }

              refresh.addEventListener(MouseEvent.CLICK, bclick);
              if (tips != null) refresh.toolTip = tips[cn];
              controlBox.addChild(refresh);
              gotControls = true;

            } else if (s[cn] == "step") {
              stepBack = new Button();
              stepBack.label="<";
              stepBack.width=20;
              stepBack.addEventListener(MouseEvent.CLICK, bclick);
              stepForward = new Button();
              stepForward.label=">";
              stepForward.width=20;
              stepForward.addEventListener(MouseEvent.CLICK, bclick);
              isStepping = true;
              if (tips != null) stepBack.toolTip = tips[cn];
              if (tips != null) stepForward.toolTip = tips[cn];
              controlBox.addChild(stepBack);
              controlBox.addChild(stepForward);
              gotControls = true;

            } else if (s[cn] == "firstlast") {
              stepFirst = new Button();
              stepFirst.label = "<|";
              stepFirst.width = 30;
              stepFirst.addEventListener(MouseEvent.CLICK, bclick);
              stepLast = new Button();
              stepLast.label = "|>";
              stepLast.width = 30;
              stepLast.addEventListener(MouseEvent.CLICK, bclick);
              if (tips != null) stepFirst.toolTip = tips[cn];
              if (tips != null) stepLast.toolTip = tips[cn];
              controlBox.addChild(stepFirst);
              controlBox.addChild(stepLast);
              gotControls = true;

            } else if (s[cn] == "setframe") {
              setFrameScrollbar = new HSlider();
              var sft:Array = getParameter("setfram_label");
              setFrameText = "Set Frame *";
              if (sft != null) setFrameText = StringUtil.trim(sft[0]);

              setFrameScrollbar.setStyle("labelOffset",0);
              setFrameScrollbar.labels = [" ",setFrameText," "];
              //setFrameScrollbar.height=40;
              setFrameScrollbar.showDataTip = false;
              setFrameScrollbar.maximum = numFrames;
              setFrameScrollbar.minimum = startFrame; 
              setFrameScrollbar.liveDragging = true;
              setFrameScrollbar.addEventListener(SliderEvent.CHANGE,changeSpeed);
              if (tips != null) setFrameScrollbar.toolTip = tips[cn];
              controlBox.addChild(setFrameScrollbar);
              gotControls = true;

            } else if (s[cn].indexOf("toggle") == 0) {
              var toggles:Array = getParameter("toggle_size");
              if (s[cn].toLowerCase().indexOf("/showall") != -1) {
                showAllOnOff = true;
              } else {
                showAllOnOff = false;
              }

              onOffWidth = 10;
              onOffHeight = 10;
              onOffSpacing = 3;

              if (toggles != null) {
                onOffWidth = parseInt(toggles[0]);
                onOffHeight = parseInt(toggles[1]);
                if (toggles.length > 2) onOffSpacing = parseInt(toggles[2]);
              }

              onOffBMD = new BitmapData(numFrames*(onOffSpacing+onOffWidth), onOffHeight+3, false, mom.getStyle("backgroundColor") );
              onOffBM = new Bitmap(onOffBMD);
              onOffSprite = new Sprite();
              onOffSprite.addChild(onOffBM);
              onOffRect = new Rectangle(0,0,onOffWidth, onOffHeight);
              onOffUI = new UIComponent();
              onOffUI.addChild(onOffSprite);
              onOffUI.height = onOffHeight+3;
              onOffUI.width = (onOffSpacing+onOffWidth)*numFrames;

              onOffState =new Array();
              for (var nof:int = 0; nof<numFrames; nof++) {
                onOffState[nof] = 0;
              }

              isOnOff = true;
              if (tips != null) onOffUI.toolTip = tips[cn];
              onOffUI.addEventListener(MouseEvent.CLICK, ooclick);
              drawOnOff();


            } else if (s[cn] == "zoom") {
              zoom = new Button();
              pLabels = getParameter("zoom_labels");
              if (pLabels == null) {
                zoomLabelTrue = "  Zoom  ";
                zoomLabelFalse = "Un-zoom";
              } else {
                zoomLabelTrue = pLabels[0];
                zoomLabelFalse = pLabels[1];
                if (pLabels.length == 3) {
                  zoom.width = parseInt(pLabels[2]);
                }
              }

              zoom.label=zoomLabelTrue;
              zoom.width=70;
              if (tips != null) zoom.toolTip = tips[cn];
              controlBox.addChild(zoom);
              activeZoom = false;
              isZooming = false;
              gotControls = true;
              zoom.addEventListener(MouseEvent.CLICK, bclick);
              showFrames(null);


            } else if (s[cn] == "fader") {
              setFaderScrollbar = new HSlider();
              var sfd:Array = getParameter("fader_label");
              setFaderText = "Use slider to fade";
              if (sfd != null) setFaderText = StringUtil.trim(sfd[0]);
              sfd = getParameter("fader_width");
              if (sfd != null) setFaderScrollbar.width = parseInt(sfd[0]);

              setFaderScrollbar.setStyle("labelOffset",0);
              setFaderScrollbar.setStyle("slideDuration",10);
              setFaderScrollbar.labels = [" ",setFaderText," "];
              setFaderScrollbar.showDataTip = false;
              setFaderScrollbar.maximum = 10*(numFrames-1);
              faderImages = new Array(10*numFrames);
              setFaderScrollbar.minimum = 0; 
              setFaderScrollbar.value = 0; 
              setFaderScrollbar.liveDragging = true;
              faderFrame = 0;
              setFaderScrollbar.addEventListener(SliderEvent.CHANGE,changeFade);
              if (tips != null) setFaderScrollbar.toolTip = tips[cn];
              controlBox.addChild(setFaderScrollbar);
              isFader = true;
              gotControls = true;
              
            } else if (s[cn] == "overlay") {
              var ols:Array = getParameter("overlay_labels");
              if (ols == null) ols = getParameter("overlay_label");
              overlayControlBox = new HBox();
              //overlayControlBox.height=30;
              overlayControlBox.setStyle("verticalGap",1);
              overlayControlContainer = new VBox();
              overlayControlContainer.setStyle("horizontalAlign","center");
              overlayControlContainer.setStyle("verticalGap",0);
              overlayControlContainer.setStyle("paddingBottom",10);

              if (ols != null) {
                var olct:Array = getParameter("overlay_labels_color");
                var olr:Array = getParameter("overlay_radio");
                var olta:Array = getParameter("overlay_transparent_amount");
                var oll:Array = getParameter("overlay_links");
                var olzo:Array = getParameter("overlay_zorder");
                var olst:Array = getParameter("overlay_static");
                var olzm:Array = getParameter("overlay_zoom");
                var olsmoo:Array = getParameter("overlay_smooth");
                var oltips:Array = getParameter("overlay_tooltip");
                var olbold:Array = getParameter("overlay_labels_bold");

                numOverlayLabels = ols.length;
                overlay = new Array(numOverlayLabels+1);  //  0=backgnd

                overlayLinks = new Array(numOverlayLabels+1);
                overlayOrder = new Array(numOverlayLabels+1);
                overlayHidden = new Array(numOverlayLabels+1);
                overlayStatic = new Array(numOverlayLabels+1);
                overlayZoom = new Array(numOverlayLabels+1);
                overlayTransparentAmount = new Array(numOverlayLabels+1);

                var doAllAsRadio:Boolean = false;
                var rbg:RadioButtonGroup;
                if (olr != null) {
                  if (olr.indexOf(",") < 0) doAllAsRadio = true;
                  rbg = new RadioButtonGroup();
                }

                var initState:Boolean = false;
                var hiddenState:Boolean = false;
                overlayHidden[i+1] = false;
                overlay[0] = null;

                for (var i:int =0; i<numOverlayLabels; i++) {
                  trace("filling in overlay sub "+i+"  lab="+ols[i]);
                  initState = false
                  hiddenState = false
                  if (startsWith(ols[i],"/") ) {
                    overlayControlContainer.addChild(overlayControlBox);
                    overlayControlBox = new HBox();
                    //overlayControlBox.height=30;
                    overlayControlBox.setStyle("verticalGap",1);

                    ols[i] = ols[i].substring(1);
                  }
                  if (endsWith(ols[i],"/on")) {
                    ols[i] = ols[i].substring(0,ols[i].length-3);
                    initState = true;
                    trace("in one");
                  } else if (endsWith(ols[i],"/always")) {
                    ols[i] = ols[i].substring(0,ols[i].length-7);
                    initState = true;
                    hiddenState = true;
                    trace("in two");
                  } else if (endsWith(ols[i],"/hidden")) {
                    ols[i] = ols[i].substring(0,ols[i].length-7);
                    initState = false;
                    hiddenState = true;
                    overlayHidden[i+1] = true;
                    trace("in three");
                  }

                  trace("filling in overlay sub "+i+"  lab="+ols[i]);
                  if (olr != null) {
                    if (startsWith(olr[i],"t") || 
                                 startsWith(olr[i],"T") ) {
                      overlay[i+1] = new RadioButton();
                      if (!hiddenState) overlay[i+1].group = rbg;
                    } else {
                      overlay[i+1] = new CheckBox();
                    }

                  } else {
                    overlay[i+1] = new CheckBox();
                  }

                  if (oltips != null) {
                    overlay[i+1].toolTip = oltips[i];
                  }

                  overlay[i+1].selected = initState;


                  if (olct != null) {
                    overlay[i+1].setStyle("color",parseHex(olct[i]));
                  }

                  if (olbold != null) {
                    if (startsWith(olbold[i],"t") || startsWith(olbold[i],"T") 
                     || startsWith(olbold[i],"b") || startsWith(olbold[i],"B") )  
                           overlay[i+1].setStyle("fontWeight","bold");
                  }

                  if (!hiddenState) {
                    overlay[i+1].label = ols[i];
                    overlay[i+1].addEventListener(MouseEvent.CLICK, cbclick);
                    overlayControlBox.addChild(overlay[i+1]);
                  }


                  if (olta == null) {
                    overlayTransparentAmount[i+1] = 100;
                  } else {
                    overlayTransparentAmount[i+1] = parseInt(olta[i]);
                  }


                  overlayLinks[0] = 0;
                  if (oll == null) {
                    overlayLinks[i+1] = 0;
                  } else {
                    overlayLinks[i+1] = parseInt(oll[i]);
                  }

                  overlayOrder[0] = 0;
                  if (olzo == null) {
                    overlayOrder[i+1] = i + 1;
                  } else {
                    var zo:int = parseInt(olzo[i]);
                    overlayOrder[zo+1] = i + 1;
                  }

                  if (olst == null) {
                    overlayStatic[i+1] = false;
                  } else {
                    if (startsWith(olst[i],"t") ||
                            startsWith(olst[i],"T") ||
                            startsWith(olst[i],"y") ||
                            startsWith(olst[i],"Y") ||
                            startsWith(olst[i],"1")) {
                      overlayStatic[i+1] = true;
                    } else {
                      overlayStatic[i+1] = false;
                    }

                  }
                  overlayStatic[0] = baseStatic;

                  imgZoomableList[0] = true;
                  if (olzm != null) {

                    if (startsWith(olzm[i], "f") ||
                           startsWith(olzm[i], "F") ||
                           startsWith(olzm[i], "n") ||
                           startsWith(olzm[i], "N")) {
                      imgZoomableList[i+1] = false
                    } else {
                      imgZoomableList[i+1] = true;
                    }
                  }
                   
                  imgSmoothList[0] = false;
                  if (olsmoo != null) {

                    if (startsWith(olsmoo[i], "t") ||
                           startsWith(olsmoo[i], "T") ||
                           startsWith(olsmoo[i], "y") ||
                           startsWith(olsmoo[i], "Y")) {
                      imgSmoothList[i+1] = true
                    } else {
                      imgSmoothList[i+1] = false;
                    }
                  }
                }


                // fix up hidden overlay initial states.....
                for (var n:int=0; n<numOverlayLabels; n++) {
                  if (overlayLinks[n+1] > 0) {
                    for (var m:int=0; m<numOverlayLabels; m++) {
                      if (overlayLinks[m+1] == -overlayLinks[n+1]) {
                        if (overlayHidden[m+1]) overlay[m+1].selected = overlay[n+1].selected;
                      }
                    }
                  }  
                }


                isOverlay = true;

              } else {
                Alert.show("Missing 'overlay_labels' parameter!");
              }


            } else {
              Alert.show(" The control parameter '"+s[cn]+"' is not recognized!");
            }
          }

          // now add the controls, overalys, and toggles if present

          if (gotControls) vbc.addChild(controlBox);

          if (overlayControlBox != null) {
            overlayControlContainer.addChild(overlayControlBox);
            vbc.addChild(overlayControlContainer);
          }

          if (onOffUI != null) vbc.addChild(onOffUI);

          // if top of view, add now; otherwise, defer
          if (ctb == 0) {
            vb.addChild(vbc);
            useBottomControls = false;
          } else {
            useBottomControls = true;
          }

        } 

      }

      if (isAutoRefresh) refreshTimer.start();

    }

    private function cbclick(event:MouseEvent): void {
      // we are here because an overlay checkbox was clicked upon

      for (var i:int = 0; i<numOverlayLabels; i++) {
        if (event.currentTarget == overlay[i+1]) {
          if (overlayLinks[i+1] > 0) {
            for (var k:int = 0; k<numOverlayLabels; k++) {
              if (overlayLinks[k+1] == -overlayLinks[i+1]) {
                if (overlayHidden[k+1]) {
                  overlay[k+1].selected = overlay[i+1].selected;
                } else {
                  if (overlay[i+1].selected) overlay[k+1].selected=true;

                }
              }
            }
          }
        }

        if (overlay[i+1] is RadioButton) {
          for (var m:int = 0; m<numOverlayLabels; m++) {
            if (overlayLinks[m+1] > 0) {
              for (k = 0; k<numOverlayLabels; k++) {
                if ( (overlayLinks[k+1] == -overlayLinks[m+1]) &&
                                               overlayHidden[k+1] ) {
                     overlay[k+1].selected = overlay[m+1].selected;
                }
              }
            }
          }
        }
       
      }

      showFrames(null);
      //event.updateAfterEvent();
    }

    private function ooclick(event:MouseEvent): void {
      var wf:int = event.localX/(onOffWidth + onOffSpacing);
      if (onOffState[wf] == -1) {
        onOffState[wf] = 0;
      } else {
        onOffState[wf] = -1;
      }

      drawOnOff();
      //event.updateAfterEvent();
      
    }

    private function changeSpeed(event:SliderEvent): void {
      if (event.currentTarget != speed) return;
      dwell = 1000 + minDwell - speed.value;
      timer.delay = dwell;
      /*
      var me:MouseEvent = new MouseEvent("slider")
      me.updateAfterEvent();
      me = null;
      */
    }

    private function changeFade(event:SliderEvent): void {
      if (event.currentTarget != setFaderScrollbar) return;
      timer.stop();  // no longer needed....
      setCurrentFrame(false, 0, false);
      if (!isShowingFrames) showFrames(null);
      // okay, so SliderEvents dont have update method, so....
      /*
      var me:MouseEvent = new MouseEvent("slider")
      me.updateAfterEvent();
      me = null;
      */
    }

    private function bdrag(event:MouseEvent) : void {
      if (event.buttonDown == false) return;
      if (zoomXFactor <= zoomXBase) return;

      if (isDragging || (Math.abs(event.localX - xScreen) > 3) || 
              (Math.abs(event.localY - yScreen) > 3) ) {

         xScreen = event.localX;
         yScreen = event.localY;
         xMove = Math.round(xScreen - xImage*zoomXFactor);
         yMove = Math.round(yScreen - yImage*zoomYFactor);

         isDragging = true;
      }

      if (!isShowingFrames) showFrames(null);
      //event.updateAfterEvent();
    }

    private function resetZoom(): void {
      zoomXFactor = zoomXBase;
      zoomYFactor = zoomYBase;

      isZooming = false;
      if (zoom != null) zoom.label = zoomLabelTrue;
      xImage = xScreen;
      yImage = yScreen;
      xMove = 0;
      yMove = 0;
    }

    private function bclick(event:MouseEvent): void {

      if (event.target == backSprite) {

        // did we click?
        if (event.type == "mouseUp") {

          if (isDragging == false) {

            if (Math.abs(event.localX - xScreen) < 3 &&
                Math.abs(event.localY - yScreen) < 3) {

               xScreen = event.localX;
               yScreen = event.localY;

              if (event.altKey) {

                resetZoom();

              } else {

                if (enableZooming) {
                  zoomXFactor = zoomXFactor + .1;
                  zoomYFactor = zoomYFactor + .1;
                }

                isZooming = true;
                xMove = Math.round(xScreen - xImage*zoomXFactor);
                yMove = Math.round(yScreen - yImage*zoomYFactor);
              }
            }

          } else {

            isDragging = false;
          }

        } else if (event.type == "mouseDown") {

          xScreen = event.localX;
          yScreen = event.localY;
          xImage = Math.round( (xScreen - xMove)/zoomXFactor);
          yImage = Math.round( (yScreen - yMove)/zoomYFactor);
          isDragging = false;
        }

        if (!isShowingFrames) showFrames(null);


      } else if (event.target == startstop) {

        if (isLooping) {
          // stop the looping
          timer.stop();
          startstop.label=startstopLabelFalse;
          isLooping = false;
        } else {
          timer.start();
          startstop.label=startstopLabelTrue;
          isLooping = true;
        }
      } else if (event.target == stepForward) {

        loopDirection = 1;
        setCurrentFrame(false, loopDirection, true);

      } else if (event.target == stepBack) {

        loopDirection = -1;
        setCurrentFrame(false, loopDirection, true);


      } else if (event.target == stepFirst) {
        setCurrentFrame(true, 0, true);

      } else if (event.target == stepLast) {
        setCurrentFrame(true, lastFrame, true);

      } else if (event.target == zoom) {
         if (enableZooming) {
           resetZoom();
           enableZooming = false;
           zoom.label = zoomLabelTrue;
         } else {
           enableZooming = true;
           zoom.label = zoomLabelFalse;
         }
         if (!isShowingFrames) showFrames(null);

      } else if (event.target == looprock) {
        isRocking = !isRocking;
        if (isRocking) {
          looprock.label = looprockLabelTrue;
        } else {
          looprock.label = looprockLabelFalse;
          loopDirection = 1;
          setCurrentFrame(false, loopDirection, false);
        }

      } else if (event.target == autoOnOff) {
        if (autoState) {
          autoOnOff.label = autoOnOffLabelTrue;
          refreshTimer.stop();
          autoState = false;
        } else {
          autoOnOff.label = autoOnOffLabelFalse;
          refreshTimer.delay = refreshRate*60*1000;
          refreshTimer.start();
          autoState = true;
        }


      } else if (event.target == refresh) {
        refreshImages(null);
      }

      event.updateAfterEvent();
    }


    private function drawOnOff():void {
      for (var nof:int = 0; nof<numFrames; nof++) {

        onOffRect.x = nof*(onOffWidth+onOffSpacing);

        if (onOffState[nof] == -1) {
          onOffBMD.fillRect(onOffRect, 0xff0000);
        } else if (onOffState[nof] == 1) {
          onOffBMD.fillRect(onOffRect, 0x0000ff);
        } else {
          onOffBMD.fillRect(onOffRect, 0x00ff00);
        }
      }
    }
    
    private function setCurrentFrame(isAbsolute:Boolean, value:int, isButton:Boolean): void {

      if (!isAbsolute) value = value * incFrame;
      if (numFrames < 0) return;
      if (isFader) {
        currentFrame = setFaderScrollbar.value;
        return;
      }

      if (isOnOff && currentFrame != -1) {
        if (onOffState[currentFrame] != -1) onOffState[currentFrame] = 0;
      }

      if (isAbsolute) {
        currentFrame = value;

      } else {
        deadFrames = 0;
        while (true) {
          currentFrame = currentFrame + value;
          if (currentFrame > lastFrame) {
            if (isRocking && !isButton) {
              currentFrame = lastFrame - incFrame;
              if (currentFrame < firstFrame) currentFrame = firstFrame;
              loopDirection = -loopDirection;
              value = -value;
            } else {
              currentFrame = firstFrame;
            }

          } else if (currentFrame < firstFrame) {
            if (isRocking && !isButton) {
              currentFrame = firstFrame + incFrame;
              loopDirection = -loopDirection;
              value = -value;
            } else {
              currentFrame = lastFrame;
            }
          }

          if (!isOnOff) break;
          if (onOffState[currentFrame] != -1) break;

          deadFrames = deadFrames + 1;
          if (deadFrames >= numFrames) {
            currentFrame = 0;
            break;
          }
        }
      }

      if (isOnOff) { 
        onOffState[currentFrame] = 1;
        drawOnOff();
      }

      if (hasFrameLabel && (frameLabels != null)) {
        frameLabelField.text = frameLabels[currentFrame];
      }

      addDwell = 0;
      if (currentFrame == (numFrames - 1)) {
        if (pausePercent > 0) {
          addDwell = (dwell * pausePercent) / 100;
        } else {
          addDwell = pauseOnLast;
        }
      }

      timer.delay = (dwell + addDwell);
      if (!isLooping && !isShowingFrames) showFrames(null);
    }




    private function showFrames(event:TimerEvent): void {
      //trace("show Frames, Timer count="+timer.currentCount+"  delay="+timer.delay+" frame="+currentFrame+" mem="+System.totalMemory);

      if (!bmBackCreated) return;
      isShowingFrames = true;
      if (event != null && isLooping) setCurrentFrame(false,loopDirection,false);
      // initialize the background
      bmBack.bitmapData.fillRect(bmRect, mom.getStyle("backgroundColor") );

      var mat:Matrix = new Matrix();
      mat.scale (zoomXFactor, zoomYFactor);
      mat.translate (xMove, yMove);

      //trace("zxf="+zoomXFactor+"  zyf="+zoomYFactor+" xM="+xMove+" yM="+yMove);
      var oo:int;

      if (isFader) {
        its = currentFrame / 10;
        var scale:int = (256 * (currentFrame % 10) )/10;

        if (bmBackLoaded[0][its] != false) {

          if (faderImages[currentFrame] == null) {

             faderImages[currentFrame] = new BitmapData(imgWidth,imgHeight,
                                    false,mom.getStyle("backgroundColor"));

             if (imgList[0][its] != null) {
                  faderImages[currentFrame].copyPixels(imgList[0][its],
                                    imgRect,upperLeft);
             }

             if (currentFrame % 10 != 0) {
               if (imgList[0][its+1] != null) 
                     faderImages[currentFrame].merge(imgList[0][its+1], 
                            imgRect,upperLeft, scale, scale, scale, scale); 
             }

          }

          bmBack.bitmapData.draw(faderImages[currentFrame], mat, 
                         null, null, bmRect);
        }


      } else {

        for (var i:int=0; i<imgList.length; i++) {
          its = currentFrame;

          if (overlayOrder == null) {
            oo = i;
          } else {
            oo = overlayOrder[i];
          }

          if (singleImage[oo]) its = 0;
          if (its > imgList[oo].length-1) its = imgList[oo].length - 1;

          //trace("bmBackLoaded="+bmBackLoaded[oo][its]+"  oo="+oo+" its="+its+" imgRect="+imgRect+" bmRect="+bmRect);
          if (bmBackLoaded[oo][its] == false) continue;

          if (i == 0 || ( (i != 0) && isOverlay && overlay[oo].selected == true)) {

            //trace("mode to show....");
            if (imgZoomableList[oo] == true) {
               if (imgList[oo][its] != null) 
                    bmBack.bitmapData.draw(imgList[oo][its], mat, 
                            null, null, bmRect, imgSmoothList[oo]);
            
            } else {

               if (imgList[oo][its] != null) 
                      bmBack.bitmapData.draw(imgList[oo][its],null,
                               null,null,bmRect,imgSmoothList[oo]);
            }

            if (i == 0 && preserve != null) {
              for (var p:int=0; p<preserve.length; p=p+4) {
                preRect.x = preserve[p];
                preRect.y = preserve[p+1];
                preRect.right = preserve[p+2];
                preRect.bottom = preserve[p+3];
                prePoint.x = preserve[p];
                prePoint.y = preserve[p+1];
                bmBack.bitmapData.copyPixels(imgList[oo][its], preRect, prePoint);
              }
            }

          }
        }
      }

      //if (event != null) event.updateAfterEvent();
      mat = null;
      event = null;
      isShowingFrames = false;
    }



      
    public function getImages() :void {

      //trace("in getImages, initialLoad = "+initialLoad);

      var fName:String = " ";

      for (var i:int=0; i<fnList.length; i++) {

        if (initialLoad) {
          imgLoaderList[i] = new Array(fnList[i].length);
          imgLoaderInfoList[i] = new Array(fnList[i].length);
          imgList[i] = new Array(fnList[i].length);

        } else if (overlayStatic[i]) {
          //trace("overlay Static = "+i);
          if (i == 0) {
            bmBackCreated = true;
            doLayoutControls = false;  // only the first time...

            // now restart as required...
            isLooping = wasLooping;
            timer.start();
          }
          continue;
        }


        for (var k:int=0; k<fnList[i].length; k++) {
          //trace("getImage i="+i+" k="+k);
          if (singleImage[i] && (k != 0) ) continue;

          try {


            if (imgLoaderList[i][k] != null) {
              imgLoaderList[i][k].unload();
            }

            imgLoaderList[i][k] = new Loader();
            imgLoaderInfoList[i][k] = imgLoaderList[i][k].contentLoaderInfo;
            imgLoaderInfoList[i][k].addEventListener(Event.COMPLETE, doneLoading);
            imgLoaderInfoList[i][k].addEventListener(IOErrorEvent.IO_ERROR, errorLoading);
            fName = fnList[i][k];

            //trace("use="+useCaching+"  doEx="+doExcludeCaching+" fName="+fName+"  exString="+excludeCaching);

            if (!useCaching || (doExcludeCaching && 
                           (fName.indexOf(excludeCaching) != -1) ) ) {

              if (useAntiCaching && fName.indexOf("?") == -1) {
                antiCacheIndex = Math.random()*1677216.0;
                fName = fName+"?"+antiCacheIndex;
              }
            }
            trace("Read file: "+fName);

            imgLoaderList[i][k].load(new URLRequest(fName));

          } catch (ioe:Error) {
            trace("Error in getImages:"+ioe);
          }
        }
      }

      initialLoad = false;
      //trace("Done with getImages....");
      
    }

    public function errorLoadingFilenames(e:IOErrorEvent) : void {
      Alert.show("Could not load file of filenames!!");
    }


    public function errorLoading(e:IOErrorEvent) : void {

      for (var i:int=0; i<imgLoaderList.length; i++) {
        // now scan each element of the overlay list
        for (var k:int=0; k<imgLoaderList[i].length; k++) {
          if (e.target == imgLoaderInfoList[i][k]) {
            trace("Error loading frame "+k+" from overlay "+i);
            imgList[i][k] = null;
            totalFrames = totalFrames - 1;
          }
        }
      }
    }

    public function doneLoading(e:Event):void {

      //trace("Enter doneLoading, usePbar = "+useProgressBar);
      if ( (pbar != null) && useProgressBar) {
        pbar.setProgress(pbar.value+1, totalFrames);
        pbar.validateNow();

        //trace("value = "+pbar.value+"  totalFrames="+totalFrames);

        if ( (pbar != null) && (pbar.value >= totalFrames)) {
          mom.removeChild(pbar);
          pbar = null;
        }
      }

      countFrames = countFrames + 1;
      if (countFrames >= totalFrames) isLoading = false;


      imgHeight = e.target.content.bitmapData.height;
      imgWidth = e.target.content.bitmapData.width;
      imgRect = new Rectangle(0,0,imgWidth, imgHeight);

      // look through imgLoaderList for match...which image is this?
      for (var i:int=0; i<imgLoaderList.length; i++) {

        // now scan each element of the overlay list
        for (var k:int=0; k<imgLoaderList[i].length; k++) {

          if (e.target.loader == imgLoaderList[i][k]) {

            //trace("matched loader for i="+i+"  k="+k);

            // element 0 is special = background image

            if (i == 0) {
            
              if (!userWindowSize) {
                bmHeight = imgHeight;
                bmWidth = imgWidth;
                bmRect = new Rectangle(0,0,bmWidth, bmHeight);

              } else {
                zoomXBase = bmWidth/imgWidth;
                zoomYBase = bmHeight/imgHeight;
                zoomXFactor = zoomXBase;
                zoomYFactor = zoomYBase;
              }


              if (imgList[i][k] != null) imgList[i][k].dispose();
              imgList[i][k] = new BitmapData(imgWidth, imgHeight, false);
              imgList[i][k].copyPixels(e.target.content.bitmapData, imgRect, upperLeft);
              //trace("imgList[i][k] width="+imgList[i][k].width);
              //trace("bmHeight = "+bmHeight+"  width="+bmWidth);

              // if first image, then make a UIComponent & Sprite for it
              if (k == 0) {

                if (backSprite != null) backSprite.removeChild(bmBack);

                bmBackground = new BitmapData(bmWidth, bmHeight, false, mom.getStyle("backgroundColor") );
                bmBack = new Bitmap(bmBackground);

                //trace("defined bmBack "+i+" width="+bmBack.bitmapData.width);
                backSprite = new Sprite();
                backSprite.addChild(bmBack);

                if (imgUIBack != null) vb.removeChild(imgUIBack);

                imgUIBack = new UIComponent();
                imgUIBack.addChild(backSprite);
                imgUIBack.height = bmHeight;
                imgUIBack.width = bmWidth;

                backSprite.addEventListener(MouseEvent.MOUSE_DOWN, bclick);
                backSprite.addEventListener(MouseEvent.MOUSE_UP, bclick);
                backSprite.addEventListener(MouseEvent.MOUSE_MOVE, bdrag);
                // now add background image...
                vb.addChild(imgUIBack);

                bmBackCreated = true;

                if (!doLayoutControls && useBottomControls) {
                  vb.removeChild(vbc);
                  doLayoutControls = true;
                }

                if (doLayoutControls && useBottomControls) {
                  vb.addChild(vbc);
                }

                doLayoutControls = false;  // only the first time...

                // now restart as required...
                isLooping = wasLooping;
                timer.start();
              }

            } else {

              var bmd:BitmapData = new BitmapData(imgWidth,imgHeight,true);

              // fix the transparent level
              bmd.threshold(e.target.content.bitmapData, imgRect, upperLeft, "==", transparency, 0x00000000, 0x00FFFFFF, true);

              if  (overlayTransparentAmount != null) {
                ct.alphaMultiplier = overlayTransparentAmount[i]/100.0;
                bmd.colorTransform(imgRect, ct);
              }

              imgList[i][k] = bmd;
              
            }  

            bmBackLoaded[i][k] = true;
          }
        }

      }
      
      //trace("exit doneLoading");
    }



    private function refreshImages(event:TimerEvent) :void {
      
      if (isLoading) return;
      timer.stop();
      timer.delay = 50;
      bmBackCreated = false;
      wasLooping = isLooping;
      isLooping = false;
      currentFrame = 0;
      if (!keepZoom) {
        isZooming = false;
        enableZooming = false;
        if (zoom != null) zoom.label=zoomLabelTrue;
        zoomXFactor = zoomXBase;
        zoomYFactor = zoomYBase;
        xMove = 0;
        yMove = 0;
      }
      isDragging = false;
      incFrame = 1;
      numFrames = 0;
      getImageFilenames();
    }
    
    private function getParameter(s:String):Array {
      for (var m:int=0; m<paramNames.length; m++) {
        if (paramNames[m] == s) {
          return paramValues[m];
        }
      }
      return null;
    }

    private function parseHex(v:String):int {
      if (startsWith(v,"0x") || startsWith(v,"0X") ) {
        return parseInt(v);
        
      } else {
        return parseInt(v.substring(1),16);
      }
    }

    private function getFirstChar(s:String):String {
      return (StringUtil.trim(s).charAt(0) );
    }

    private function startsWith(s:String, match:String):Boolean {
      return !StringUtil.trim(s).indexOf(match);
    }

    private function endsWith(s:String, match:String):Boolean {

      return ( (StringUtil.trim(s).lastIndexOf(match) > 0) && 
         (StringUtil.trim(s).lastIndexOf(match) == (StringUtil.trim(s).length - match.length)));
    }


    private function getNamesUsingBaseName(fn:String, count:int): Array {
      var filenames:Array = new Array(count);
      for (var i:int=0; i<count; i++) {
        var val:int = i+baseNumber;
        if (fn.indexOf("*") >= 0) {
          filenames[i] = fn.replace("*",String(val));
        } else if (fn.indexOf("?") > 0) {
          filenames[i] = fn.replace("?",String(val));
        } else {
          filenames[i] = fn+i;
        }

      }
      return filenames;
    }


  }

}