;+
; NAME:
;	hxisSTRLABEL
; PURPOSE:
;	Return strings for plot title, quantity and cgs units
; CALLING SEQUENCE:
;	hxisSTRLABEL,BTYP,BLOW,BUP,CLAB,QUANT,CUNIT
; INPUTS:
;	BTYP		band settings as selected by SELECT
;	BLOW		(same meaning as INFO.BYP,INFO.BLOW,INFO.BUP)
;	BUP
; OUTPUTS:
;	CLAB		title: energy bands used (keV)
;	QUANT		physical quantity (count rates, temp, etc.)
;	CUNIT		cgs units of QUANT
; MODIFICATION HISTORY:
;	OCT-90, Paul Hick (ARC)
;-

pro hxisSTRLABEL, BTYP,BLOW,BUP,CLAB,QUANT,CUNIT


EBAND = ['3.5','5.5','8','11.5','16','22','30']	; Nominal (gain=1.0) energy band boundaries in kev

if BTYP eq 0 then begin

    CLAB = EBAND(BLOW-1)+'-'+EBAND(BUP)+' keV'	; Energy band label
    QUANT = 'C!I'+strcompress(BLOW, /remove_all)
    if BLOW ne BUP then QUANT = QUANT+'-'+strcompress(BUP, /remove_all)
    QUANT = QUANT+'!N'  &  CUNIT = 'cnts s!u-1'

endif else if BTYP eq 1 then begin

    CLAB = EBAND(BUP-1)+'-'+EBAND(BUP)+' keV'+'/'+EBAND(BLOW-1)+'-'+EBAND(BLOW)+' keV'
    QUANT = 'T!I'+strcompress(BLOW, /remove_all)+'-'+strcompress(BUP,/remove_all)+'!N'
    CUNIT = '10!E6!N K'

endif else if BTYP eq 2 then begin

    CLAB = EBAND(BUP-1)+'-'+EBAND(BUP)+' keV'+'/'+EBAND(BLOW-1)+'-'+EBAND(BLOW)+' keV'
    QUANT = 'E!I'+strcompress(BLOW, /remove_all)+'-'+strcompress(BUP,/remove_all)+'!N'
    CUNIT = '10!E48!N cm!E-3!N'

endif else if BTYP eq 3 then begin

    CLAB = EBAND(BUP-1)+'-'+EBAND(BUP)+' keV'+'/'+EBAND(BLOW-1)+'-'+EBAND(BLOW)+' keV'
    A = strcompress(BLOW, /remove_all)+'-'+strcompress(BUP,/remove_all)
    QUANT = 'k!IB!N*T!I'+A+'!N*E!I'+A+'!N'
    CUNIT = '10!E38!N erg cm!E-3!N'

endif else begin

    message, 'Invalid BTYP'

endelse

return  &  end